mirror of
https://github.com/simplex-chat/simplex-chat.git
synced 2026-10-15 15:30:36 +00:00
spaced4ndyandEvgeny Poberezkin
e05a35e26e
* postgres: modules structure (#5401) * postgres: schema, field conversions (#5430) * postgres: rework chat list pagination query (#5441) * prepare cabal for merge * restore cabal changes * simplexmq * postgres: implementation wip (tests don't pass) (#5481) * restore ios file * postgres: implementation - tests pass (#5487) * refactor DB options * refactor * line * style * style * refactor * $ * update simplexmq * constraintError * handleDBErrors * fix * remove param * Ok * case * case * case * comment --------- Co-authored-by: Evgeny Poberezkin <evgeny@poberezkin.com>
92 lines
3.2 KiB
Haskell
92 lines
3.2 KiB
Haskell
{-# LANGUAGE ApplicativeDo #-}
|
|
{-# LANGUAGE DuplicateRecordFields #-}
|
|
{-# LANGUAGE NamedFieldPuns #-}
|
|
{-# LANGUAGE OverloadedStrings #-}
|
|
{-# LANGUAGE ScopedTypeVariables #-}
|
|
|
|
module Broadcast.Options where
|
|
|
|
import Data.Maybe (fromMaybe)
|
|
import Data.Text (Text)
|
|
import Options.Applicative
|
|
import Simplex.Chat.Bot.KnownContacts
|
|
import Simplex.Chat.Controller (updateStr, versionNumber, versionString)
|
|
import Simplex.Chat.Options (ChatCmdLog (..), ChatOpts (..), CoreChatOpts, coreChatOptsP)
|
|
|
|
data BroadcastBotOpts = BroadcastBotOpts
|
|
{ coreOptions :: CoreChatOpts,
|
|
publishers :: [KnownContact],
|
|
welcomeMessage :: Text,
|
|
prohibitedMessage :: Text
|
|
}
|
|
|
|
defaultWelcomeMessage :: [KnownContact] -> Text
|
|
defaultWelcomeMessage ps = "Hello! I am a broadcast bot.\nI broadcast messages to all connected users from " <> knownContactNames ps <> "."
|
|
|
|
defaultProhibitedMessage :: [KnownContact] -> Text
|
|
defaultProhibitedMessage ps = "Sorry, only these users can broadcast messages: " <> knownContactNames ps <> ". Your message is deleted."
|
|
|
|
broadcastBotOpts :: FilePath -> FilePath -> Parser BroadcastBotOpts
|
|
broadcastBotOpts appDir defaultDbName = do
|
|
coreOptions <- coreChatOptsP appDir defaultDbName
|
|
publishers <-
|
|
option
|
|
parseKnownContacts
|
|
( long "publishers"
|
|
<> metavar "PUBLISHERS"
|
|
<> help "Comma-separated list of publishers in the format CONTACT_ID:DISPLAY_NAME whose messages will be broadcasted"
|
|
<> value []
|
|
)
|
|
welcomeMessage_ <-
|
|
optional $
|
|
strOption
|
|
( long "welcome"
|
|
<> metavar "WELCOME"
|
|
<> help "Welcome message to be sent to all connecting users (default message will list allowed publishers)"
|
|
)
|
|
prohibitedMessage_ <-
|
|
optional $
|
|
strOption
|
|
( long "prohibited"
|
|
<> metavar "PROHIBITED"
|
|
<> help "Reply to non-publishers who try to send messages (default reply will list allowed publishers)"
|
|
<> showDefault
|
|
)
|
|
pure
|
|
BroadcastBotOpts
|
|
{ coreOptions,
|
|
publishers,
|
|
welcomeMessage = fromMaybe (defaultWelcomeMessage publishers) welcomeMessage_,
|
|
prohibitedMessage = fromMaybe (defaultProhibitedMessage publishers) prohibitedMessage_
|
|
}
|
|
|
|
getBroadcastBotOpts :: FilePath -> FilePath -> IO BroadcastBotOpts
|
|
getBroadcastBotOpts appDir defaultDbName =
|
|
execParser $
|
|
info
|
|
(helper <*> versionOption <*> broadcastBotOpts appDir defaultDbName)
|
|
(header versionStr <> fullDesc <> progDesc "Start chat bot with DB_FILE file and use SERVER as SMP server")
|
|
where
|
|
versionStr = versionString versionNumber
|
|
versionOption = infoOption versionAndUpdate (long "version" <> short 'v' <> help "Show version")
|
|
versionAndUpdate = versionStr <> "\n" <> updateStr
|
|
|
|
mkChatOpts :: BroadcastBotOpts -> ChatOpts
|
|
mkChatOpts BroadcastBotOpts {coreOptions} =
|
|
ChatOpts
|
|
{ coreOptions,
|
|
deviceName = Nothing,
|
|
chatCmd = "",
|
|
chatCmdDelay = 3,
|
|
chatCmdLog = CCLNone,
|
|
chatServerPort = Nothing,
|
|
optFilesFolder = Nothing,
|
|
optTempDirectory = Nothing,
|
|
showReactions = False,
|
|
allowInstantFiles = True,
|
|
autoAcceptFileSize = 0,
|
|
muteNotifications = True,
|
|
markRead = False,
|
|
maintenance = False
|
|
}
|